The Problem:

My boss emails me numbered lists of tasks for everyone in the office. When I put them into our Assignment template, I need to delete all the numbers he's typed in, because the lists get automatic numbering from the styles. I know I can go through selecting each list and then clicking the Numbering button on the Formatting toolbar twice, once to remove the numbers and once to reapply them, but that messes up the list templates.

The Solution:

Create the short macro shown in Example 8-7 to remove the manually applied numbers from a selected list.

WordBasic was the programming language used in early versions of Word, before Microsoft applied VBA to Word. VBA includes a WordBasic object that enables you to use WordBasic commands, such as this one, via VBA.

Example 8-7. A macro to remove manual numbering from a list

Sub Remove_Manual_List_Numbering()
    WordBasic.ToolsBulletsNumbers Replace:=0, Type:=1, Remove:=1
End Sub

The Problem:

The Title Case option in the Change Case dialog box (Format Change Case) makes the first letter of each word uppercase and the remaining letters lowercase. But conjunctions and short prepositions (five letters or fewer, according to the magazine I work for) should be all lowercase.

The Solution:

A macro can fix most of these errors, although you will need to check prepositions that need initial capitals because they are part of a verb. Example 8-8 shows the macro.

---

Tip: If you're familiar with VBA, you'll probably find the extended Or condition cumbersomenot to mention a lot of typing. You can make the code more compact by using a Select Case statement instead of the if statement, using Case "a", "above", "after", "an", and so on.

---

The code in the macro is fairly straightforward:

• In the first group of statements, the macro declares two variables: a String variable named strL and an Integer variable named i.

• In the second group of statements, the macro selects the appropriate paragraph. The first statement compares the selection type to wdInsertionPoint the "selection" being a point in the text rather than an actual selection of characters or other objects. If the selection is not an insertion point, the macro collapses the selection to an insertion point. The second statement selects the first paragraph of the (collapsed) selectionin other words, the paragraph in which the insertion point is located. Selecting the paragraph also selects the paragraph mark at its end, and this paragraph mark counts as a "word." So, to work with only the real words, the third statement shortens the selection by one character to the left, deselecting the paragraph mark.

• The third group of statements applies title case (first letter capitalized) to the first and last words in the selection, because the first and last words in a heading must always be capitalized even if they're short prepositions or conjunctions.

• The fourth group of statements uses a For... Next loop to check each of the remaining words in the selection against a list of short prepositions and conjunctions. (Adjust this list to meet your company's style demands.) The loop runs from 2 (the second word) to Selection.Words.Count - 1, or the number of words in the paragraph minus 1 (so as not to affect the last word, to which title case has already been applied). The second statement assigns to strL the lowercase (LCase) version of the currently selected word, with any leading or trailing spaces trimmed off it (when you double-click to select a word, VBA includes any spaces after the word). Using the lowercase version of the word is necessary because the comparison is case-sensitive. The If statement then compares strL to the list of prepositions and conjunctions. If there's a match, Word applies lowercase to the word; if not, the Else statement applies title case to the word.

• Finally, the Selection.Collapse statement collapses the selection to its end, which is equivalent to pressing to deselect a selection.

Example 8-8. A macro to apply proper capitalization to a title

 Sub Apply_Proper_Capitalization()

   'applies proper capitalization to the first paragraph in the selection

    Dim strL As String
    Dim i As Integer

    If Selection.Type <> wdSelectionIP Then Selection.Collapse
    Selection.Paragraphs(1).Range.Select
    Selection.MoveLeft Unit:=wdCharacter, Count:=1, Extend:=wdExtend

    Selection.Words(1).Case = wdTitleWord
    Selection.Words(Selection.Words.Count).Case = wdTitleWord

    For i = 2 To Selection.Words.Count - 1
      strL = LCase(Trim(Selection.Words(i)))
      If strL = "a" Or strL = "above" Or strL = "after" Or strL = "an" Or _
      strL = "and" Or strL = "as" Or strL = "at" Or strL = "below" Or _
      strL = "but" Or strL = "by" Or strL = "down" Or strL = "for" Or _
      strL = "from" Or strL = "in" Or strL = "into" Or strL = "of" Or _
      strL = "off" Or strL = "on" Or strL = "onto" Or strL = "or" Or _
      strL = "out" Or strL = "over" Or strL = "the" Or strL = "to" Or _
      strL = "under" Or strL = "up" Or strL = "with" Then
        Selection.Words(i).Case = wdLowerCase
      Else
        Selection.Words(i).Case = wdTitleWord
     End If
  Next i

  Selection.Collapse Direction:=wdEnd

End Sub

---

Tip: This macro isn't perfect, as it ignores the possibility of periods or other punctuation requiring prepositions or conjunctions to be title case in the middle of a paragraph. You might adapt the macro to take care of this need. You might also add a list of uppercase terms (for example, XP) or intercapitalized terms (for example, iPod) that require special treatment.

---

The Problem:

The Title Case option in the Change Case dialog box (Format Change Case) makes the first letter of each word uppercase and the remaining letters lowercase. But conjunctions and short prepositions (five letters or fewer, according to the magazine I work for) should be all lowercase.

The Solution:

A macro can fix most of these errors, although you will need to check prepositions that need initial capitals because they are part of a verb. Example 8-8 shows the macro.

---

Tip: If you're familiar with VBA, you'll probably find the extended Or condition cumbersomenot to mention a lot of typing. You can make the code more compact by using a Select Case statement instead of the if statement, using Case "a", "above", "after", "an", and so on.

---

The code in the macro is fairly straightforward:

• In the first group of statements, the macro declares two variables: a String variable named strL and an Integer variable named i.

• In the second group of statements, the macro selects the appropriate paragraph. The first statement compares the selection type to wdInsertionPoint the "selection" being a point in the text rather than an actual selection of characters or other objects. If the selection is not an insertion point, the macro collapses the selection to an insertion point. The second statement selects the first paragraph of the (collapsed) selectionin other words, the paragraph in which the insertion point is located. Selecting the paragraph also selects the paragraph mark at its end, and this paragraph mark counts as a "word." So, to work with only the real words, the third statement shortens the selection by one character to the left, deselecting the paragraph mark.

• The third group of statements applies title case (first letter capitalized) to the first and last words in the selection, because the first and last words in a heading must always be capitalized even if they're short prepositions or conjunctions.

• The fourth group of statements uses a For... Next loop to check each of the remaining words in the selection against a list of short prepositions and conjunctions. (Adjust this list to meet your company's style demands.) The loop runs from 2 (the second word) to Selection.Words.Count - 1, or the number of words in the paragraph minus 1 (so as not to affect the last word, to which title case has already been applied). The second statement assigns to strL the lowercase (LCase) version of the currently selected word, with any leading or trailing spaces trimmed off it (when you double-click to select a word, VBA includes any spaces after the word). Using the lowercase version of the word is necessary because the comparison is case-sensitive. The If statement then compares strL to the list of prepositions and conjunctions. If there's a match, Word applies lowercase to the word; if not, the Else statement applies title case to the word.

• Finally, the Selection.Collapse statement collapses the selection to its end, which is equivalent to pressing to deselect a selection.

Example 8-8. A macro to apply proper capitalization to a title

 Sub Apply_Proper_Capitalization()

   'applies proper capitalization to the first paragraph in the selection

    Dim strL As String
    Dim i As Integer

    If Selection.Type <> wdSelectionIP Then Selection.Collapse
    Selection.Paragraphs(1).Range.Select
    Selection.MoveLeft Unit:=wdCharacter, Count:=1, Extend:=wdExtend

    Selection.Words(1).Case = wdTitleWord
    Selection.Words(Selection.Words.Count).Case = wdTitleWord

    For i = 2 To Selection.Words.Count - 1
      strL = LCase(Trim(Selection.Words(i)))
      If strL = "a" Or strL = "above" Or strL = "after" Or strL = "an" Or _
      strL = "and" Or strL = "as" Or strL = "at" Or strL = "below" Or _
      strL = "but" Or strL = "by" Or strL = "down" Or strL = "for" Or _
      strL = "from" Or strL = "in" Or strL = "into" Or strL = "of" Or _
      strL = "off" Or strL = "on" Or strL = "onto" Or strL = "or" Or _
      strL = "out" Or strL = "over" Or strL = "the" Or strL = "to" Or _
      strL = "under" Or strL = "up" Or strL = "with" Then
        Selection.Words(i).Case = wdLowerCase
      Else
        Selection.Words(i).Case = wdTitleWord
     End If
  Next i

  Selection.Collapse Direction:=wdEnd

End Sub

---

Tip: This macro isn't perfect, as it ignores the possibility of periods or other punctuation requiring prepositions or conjunctions to be title case in the middle of a paragraph. You might adapt the macro to take care of this need. You might also add a list of uppercase terms (for example, XP) or intercapitalized terms (for example, iPod) that require special treatment.

---

The Problem:

Call me paranoid, but I think Word may really be out to get meor perhaps it's just that I'm working with master documents. Anyway, Word seems unstable, and I want to keep a backup copy of each document I'm working with while I'm working with it. It seems to me that Word's automatic backup copy would be just about ideal, if it were a copy of my most recent save rather than the last-but-one save. With the speed at which I'm trying to make progress on my documents, even losing a couple of minutes' worth of changes is painful.

The Solution:

Create a macro to force Word to save the document twice in immediate succession. Call the macro FileSave so that it replaces Word's built-in Save command and picks up its keyboard shortcut (Ctrl+S).

If you simply want to double-save the document, all you need is the macro shown in Example 8-9.

Example 8-9. A macro to save the active document twice in succession

  Sub FileSave()

     Options.CreateBackup = True

     ActiveDocument.Save
     ActiveDocument.Saved = False
     ActiveDocument.Save

  End Sub

The Options.CreateBackup = True statement ensures that the "Always create backup copy" feature is on (you can also set it by choosing Tools Options, clicking the Save tab, and checking the "Always create backup copy" box).

But if you really need to safeguard your work, you can adapt the macro so that it automatically copies the backup document to a safe locationfor example, a network drive, as in Example 8-10.

This macro declares three String variables to store the text it uses for naming the documents. It assigns to strDocName the name of the active document and assigns to strWordBackupDoc a string consisting of the full name (including the path) that Word gives the backup document for the active document. For example, if the active document is named Example.doc and is located in the C:\Samples folder, its backup document is named C:\Samples\Backup of Example.wbk.

The macro assigns to strMyBackupDoc the path and name for the backup document that you want to create. In this example, the macro assigns the backup document the path Z:\Publi-c\Backups\ (change it as needed, and use the notation \\server\folder\ if the drive isn't mapped to a letter), the basic filename, the word "backup," the date in yyyy-mm-dd format, and the time in hh-mm-ss AMPM format. In other words, the backup document for Example.doc will have a name such as Example backup 2005-05-27 04-14-38 PM.doc.

Finally, the FileCopy statement copies the file specified by strWordBackupDoc to strMyBackupDoc. If there's already a file with that name in the backup folder, it will be overwritten, but unless you save twice within a second, this shouldn't happen.

Example 8-10. A macro to back up the active document's default backup copy to a network drive

 Sub FileSave()

    Dim strDocName As String
    Dim strWordBackupDoc As String
    Dim strMyBackupDoc As String

    Options.CreateBackup = True

    ActiveDocument.Save
    ActiveDocument.Saved = False
    ActiveDocument.Save

    strDocName = ActiveDocument.Name

    strWordBackupDoc = ActiveDocument.Path & "\Backup of " & _
       Left(strDocName, Len(strDocName) - 3) & "wbk"

    strMyBackupDoc = "Z:\Public\Backups\" & Left(strDocName, _
      Len(strDocName) - 4) & " backup " & Format(Date, "yyyy-mm-dd") & _
      " " & Format(Time, "hh-mm-ss AMPM") & ".doc"

    FileCopy strWordBackupDoc, strMyBackupDoc
  End Sub

The Problem:

Changing the Compatibility settings in the Options dialog box so that I can legibly print a document that contains color text on my monochrome printer is getting kinda old. Automate it for me already!

The Solution:

Right you are. Create a macro that looks like Example 8-11.

This macro creates two Boolean variables, which are variables that can only be true or False. It then checks to see if the number of open documents is 0; if so, it stops running the macro so as to avoid the error that results from trying to print without a document open.

Example 8-11. A macro to print the active document in monochrome

 Sub Print_Active_Document_in_Monochrome()
    Dim blnBWOn As Boolean
    Dim blnDocClean As Boolean

   If Documents.Count = 0 Then Exit Sub

   With ActiveDocument
      blnDocClean = .Saved
      blnBWOn = .Compatibility(wdPrintColBlack)
      .Compatibility(wdPrintColBlack) = True
      Dialogs(wdDialogFilePrint).Show
      .Compatibility(wdPrintColBlack) = blnBWOn
      .Saved = blnDocClean
   End With
 End Sub

For the bulk of its code, the macro uses a With statement referring to the active document. It stores the current state of the document's Saved property (TRue if the document contains no unsaved changes, False if it does contain some) in the blnDocClean variable, and the state of the Compatibility (wdPrintColBlack) setting (whether the "Print colors as black on noncolor printers" checkbox on the Compatibility tab of the Options dialog box is checked) in the blnBWOn variable.

The macro then sets Compatibility(wdPrintColBlack) to true and displays the Print dialog box so that the user can print the document. Finally, the macro restores Compatibility(wdPrintColBlack) and Saved to the values stored in the two variables.

The Problem:

When I'm working on a document, I often want to finish editing a page, print it, check it, and then print another page. But the Print dialog box always appears with the All option selected in the Page Range group box.

The Solution:

With a short macro (see Example 8-12), you can make the Print dialog box appear with the Current Page option, the Pages option, or the Selection option selected instead. If you select the Pages option, you can specify the range of pages to print, as in the example.

Example 8-12. A macro to display the Print dialog box with print options preselected

 Sub Display_Print_Dialog_Custom()
     With Dialogs(wdDialogFilePrint)
         .Range = wdPrintRangeOfPages
         .Pages = "3,5,7-11"
         If .Show = -1 Then .Execute
     End With
 End Sub

The With statement works with the wdDialogFilePrint member of the Dialogs collectionin other words, the Print dialog box. The commands inside the With statement control the options selected:

• To select the Current Page option, use this statement:

      .Range = wdPrintCurrentPage
  

  
  

• To select the Pages option and specify a simple range of pages, use these statements, substituting suitable numbers on the From and To lines:

      .Range = wdPrintFromTo
      .From = "2"
      .To = "4"
  

  
  

• To select the Pages option and specify a complex range of pages, use these statements, substituting suitable numbers on the Pages line:

      .Range = wdPrintRangeOfPages
      .Pages = "3,5,7-11"
  

  
  

The Show method displays the dialog box and returns a value for the button the user clicks. If the value is -1, which indicates that the user clicked the OK button, the Execute command executes the instructions contained in the dialog box. If the user clicks the Cancel button, VBA does not execute the instructions.

The Problem:

I tried the replace-with-subscript trick mentioned in (see "Replace with a Subscript"), and it's fine as far as it goes. But what I need to do is find each table caption; check to see if the paragraph before it uses a boxed style; and, if it doesn't, apply a top border to the table caption. I can't do that with Replace, now can I?

The Solution:

Not as you describe it, no. But a macro using Find can locate the table captions, check them, and apply the border as needed. The macro shown in Example 8-13 searches for each paragraph using the Table Caption style and applies a top border to that paragraph if the previous paragraph doesn't have a bottom border. You'll need to adapt the specifics, but the principle should work for you.

Example 8-13. A macro to search for specific formatting and check nearby formatting

 Sub Check_Table_Captions()

     'go through the document for paragraphs in the Table Caption style
     'check if the paragraph before has a bottom border
     'if not, apply a top border to the Table Caption paragraph

     Dim i As Integer
     Dim strMTitle As String

     On Error GoTo ErrorHandler

     strMTitle = "Apply Upper Border to Table Caption Style"

    If MsgBox(Prompt:="Apply the upper borders to the Table Caption style?", _
       Buttons:=vbYesNo + vbQuestion, Title:=strMTitle) = vbNo Then
       Exit Sub
  End If
  For i = 2 To ActiveDocument.Paragraphs.Count
       With ActiveDocument.Paragraphs(i)
           .Range.Select
          If .Style = "Table_Caption" Then
              If .Previous.Borders(wdBorderBottom).LineStyle <> _
                 wdLineStyleSingle Then
                .Borders(wdBorderTop).LineStyle = wdLineStyleSingle
                .Borders(wdBorderTop).LineWidth = wdLineWidth100pt
                .Borders(wdBorderTop).Color = wdColorBlack
             End If
         End If
      End With
   Next i

 ErrorHandler:
  If Err.Number = 5834 Then
      MsgBox Prompt:="This document doesn't use the Table Caption style.", _
         Buttons:=vbOKOnly + vbInformation, Title:=strMTitle
      Exit Sub
  Else
      MsgBox Prompt:="The following error has occurred:" & vbCr & vbCr & _
          "Error Number: " & Err.Number & vbCr & vbCr & _
          "Error Description: " & Err.Description, _
          Buttons:=vbOKOnly + vbInformation, Title:=strMTitle
      Exit Sub
    End If
  End Sub

Much of this macro is straightforward if you've been following along through this tutorial, but the following points are worth noting:

• The On Error GoTo ErrorHandler line tells VBA to trap errors and directs them to an error handler (a section of code designed to deal with errors). Unhandled errors in your macros usually display error message boxes, which are confusing for users, as many of the errors are hard to interpret. The error this macro is most likely to encounter is the active document not containing the Table Caption style. If this happens, the code after the ErrorHandler: label at the end of the macro runs, checking the error number against the number for a missing style (5834); if it matches, the error handler displays a message box explaining what has happened and then exits the macro. If there's a different error, the Else statement makes the macro display a message box giving the error's number and description. This information tends to be neither intelligible nor helpful, but it's preferable to having an error message box named Microsoft Visual Basic appear unexpectedly on the screen.

• The For loop uses a counter (i) and runs from i = 2 to ActiveDocument.Paragraphs.Count, which is the number of paragraphs in the document. This loop enables the macro to check every paragraph in the document (skipping the first paragraph, which doesn't have a paragraph before it) for the Table Caption style.

• The With statement works with the paragraph the loop is currently examining (ActiveDocument.Paragraphs(i)). If the paragraph's style is Table Caption, the nested If statement checks to see if the previous paragraph (.Previous) is lacking a bottom border. If it is, the three .Borders statements apply the necessary border.

The Problem:

I need a printout of all the fonts that Word can offer me. I'm sick of scrolling through the font list trying to find one that looks okay.

The Solution:

Try the macro shown in Example 8-14.

Here's what the macro does:

Example 8-14. A macro to list all the fonts available to Word, with a sample of each font

  Sub List_All_Fonts()
      'Lists all the fonts available to Word with the current printer driver

      Dim strFont As Variant
      Dim strText As String

      strText = InputBox(Prompt:= _
          "Type the sample text you want to use in the font listing:", _
          Title:="List All Fonts", _
          Default:="The five boxing wizards jump quickly.")
      If strText = "" Then Exit Sub

      Documents.Add
      For Each strFont In FontNames
          Selection.Font.Reset
          Selection.TypeText strFont & "parahere"
          Selection.Font.Name = strFont
          Selection.TypeText strText & vbCr
      Next

      ActiveDocument.Content.Select
      Selection.Sort FieldNumber:="Paragraphs", _
          SortFieldtype:=wdSortFieldAlphanumeric

      With Selection.Find
          .ClearFormatting
          .MatchCase = False
          .MatchAllWordForms = False
          .MatchWholeWord = False
          .MatchSoundsLike = False
          .MatchWildcards = False
          .Forward = True
          .Wrap = wdFindContinue
          .Text = "parahere"
          .Replacement.Text = "parahere^p"
          .Execute Replace:=wdReplaceAll
          .Text = "parahere"
          .Replacement.Style = "Heading 2"
          .Execute Replace:=wdReplaceAll
          .Replacement.ClearFormatting
          .Replacement.Text = ""
          .Execute Replace:=wdReplaceAll
          .Text = ""
      End With

      Selection.Collapse Direction:=wdCollapseStart
      Selection.Paragraphs(1).Style = "Heading 1"
      Selection.TypeText "List of Fonts Available to Word"
      MsgBox "The macro has created a list showing the fonts currently " _
         & "available to Word." & vbCr & vbCr & _
        "Please save this document if you want to keep it.", _
        vbOKOnly + vbInformation, "List All Fonts Macro"

    End Sub

The Problem:

I reckon I've more or less gotten the hang of the Visual Basic Editor by nowat least, I can create and edit macros in different projects. But do you mean to tell me that I need to use Cut and Paste to move a macro from one project to another?

The Solution:

You've hit upon one of the Visual Basic Editor's most dramatic shortcomings: the inability to copy or move a macro quickly from one project (a template or document) to another. But Word itself can take care of this task: choose Tools Macro Macros, click the Organizer button in the Macros dialog box, and then click the Macro Project Items tab. See which projects are open in the two "Macro Project Items available in" boxes; if necessary, click the Close File button to close one of the open projects, and then use the resulting Open File button to open the relevant project. With the projects open, select the item you want to copy, and click the Copy button. To move an item, copy it to the new location and then click the Delete button to delete it from the source project.

When you've finished copying or moving items, click the Close button to close the Organizer dialog box, and save the documents or templates with which you've been working.

The Problem:

When I open the template that one of my colleagues has developed, Word says that the macros are disabled and tells me to check the host application's online help or documentation. Help! What's a host application, what's the problem, andmost of allhow do I fix it?

The Solution:

Visual Basic for Applications is what's called a hosted programming language: instead of running on its own, as Visual Basic itself does, VBA requires a host application to provide it with an environment in which to work. Word is the host application here; the other Office applications, and many other applications, also host VBA.

The problem is that Word's security settings are set to protect you from potentially dangerous code. Because VBA can take a wide variety of actions on your computer without your intervention, it's a security threat. Consequently, Microsoft has bundled up Word (and the other Office applications) increasingly tightly against malefaction. When you open a VBA project that might be dangerous, Word disables its macros (see Figure 8-5).

Figure 8-5. If Word automatically disables macros that you need to run, you may need to change your security settings.

To change the security settings so that you can run the macros (assuming that you trust the template's creator not to use them to wreak havoc on your machine), choose Tools Macro Security and select the appropriate option on the Security Level tab (see Figure 8-6). Word 2003 offers Very High, High, Medium, and Low levels; Word XP and Word 2000 do not offer the Very High level. Here's what you need to know about the details:

Trusted locations

By default, Word trusts macros in templates and add-ins (for example, global templates) installed on your computer. So, even if you set the security level to Very High or High, you can still run any macros that you create yourself. To prevent Word from trusting installed templates and add-ins, uncheck the "Trust all installed add-ins and templates" box on the Trusted Publishers tab (Trusted Sources tab in Word XP and Word 2000).

Figure 8-6. The Security Level tab lets you control whether Word will run macros that are not signed with digital signatures or installed in trusted locations.

Trusted publishers/trusted sources

Trusted publishers (in Word 2003), also known as trusted sources (in Word XP or Word 2000), are people or entities for whom a digital certificate is installed on your computer and who are designated as trustworthy. You can view the list on the Trusted Publishers tab or Trusted Sources tab. If you administer your computer, you will probably be able to add trusted publishers or sources; if so, Word will prompt you when you open a document, template, or add-in that has been signed by a digital certificate that's not yet trusted. In a corporate network, network administrators usually manage trusted sources.

---

Tip: A digital certificate is encrypted code that uniquely identifies its holder. Digital certificates are available from certification authorities (CAs) such as VeriSign (http://www.verisign.com), Thawte (http://www.thawte.com; a VeriSign company), and GlobalSign NV (http://www.globalsign.com). Some companies also issue digital certificates to their own staff from in-house CAs.

---

Signed and unsigned macros

A signed macro is one that has been digitally signed by the holder of a digital certificate. Being signed doesn't mean that the macro is necessary benevolent or trustworthy, just that it has some form of audit trail attached to it. Similarly, being unsigned doesn't necessarily mean that a macro is malicious.

---

Tip: If you distribute your macros to other people, you will need to sign them to ensure that they are trusted. Once you've installed a digital certificate on your PC, you can sign a macro project (for example, a template) in the Visual Basic Editor: click the project in the Project Explorer, choose Tools Digital Signature, click the Choose button, pick the certificate in the Select Certificate dialog box, and click the OK button to close each dialog box.

---

The Problem:

I've been putting AutoText entries, keyboard shortcuts, and custom toolbars and menus in Normal.dot so that they're available to all my documents. But I've had to delete and rebuild Normal.dot twice in the last couple of months, which was a huge waste of time.

The Solution:

When Normal.dot gets cranky, Word's foundations start to quiver.

Your first line of defense is to back up Normal.dot often, so that even if it does get corrupted, you can recover quickly using an older version. But if Normal.dot is starting to corrupt frequently, you're probably keeping too much information in it, so you should transfer as much as possible of that information into other locations.

Create a new template and save it. With the template still open, choose Tools Macro Macros, and click the Organizer button. Use the controls on the Organizer dialog box's four tabs to move the AutoText entries, keyboard shortcuts, and custom toolbars and menus to the new template. Save the template and close it.

Still in Word, choose Tools Templates and Add-Ins, click the Add button, navigate to and select the template, and then click the OK button to load it as a global template. Back up this global template frequently as well, in case it too sustains corruption.

---

Tip: You can load the global template automatically, if you prefer, by placing it in your Word Startup folder. Choose Start Run, type %userprofile%\Application Data\Microsoft\Word\Startup, and press Enter to open a Windows Explorer window to your Word Startup folder.

---